Рисуем график функции в Delphi
Материал из DRKB
Учебная статья рисования функции[править | править код]
В этой статье мы рассмотрим несколько способов нарисовать график какой-нибудь функции. Рисовать график мы будем на канве компонента Image.
Рисование по пикселам[править | править код]
Рисовать на канве можно разными способами. Первый вариант - рисовать по пикселям. Для этого используется свойство канвы Pixels. Это свойство представляет собой двумерный массив, который отвечает за цвета канвы. Например Canvas.Pixels[10,20] - соответствует цвету пикселя с координатами (10,20). С массивом пикселей можно обращаться, как с любым свойством: изменять цвет, задавая пикселю новое значение, или определять его цвет, по хранящемуся в нем значению. На примере ниже мы зададим черный цвет пикселю с координатами (10,20):
Canvas.Pixels[10, 20] := clBlack;
Теперь мы попробуем нарисовать график функции F(x), если известен диапазон ее изменений Ymax и Ymin, и диапазон изменения аргумента Xmax и Xmin. Для этого мы напишем пользовательскую функцию, которая будет вычислять значение функции F в точке x, а также будет возвращать максимум и минимум функции и ее аргумента.
function TForm1.F(x: Real; var Xmax, Xmin, Ymax, Ymin: Real): Real;
begin
Result := Sin(x);
Xmax := 4 * pi;
Xmin := 0;
Ymax := 1;
Ymin := -1;
end;
Не забудьте также указать заголовок этой функции в разделе public
public
{ Public declarations }
function F(x: Real; var Xmax, Xmin, Ymax, Ymin: Real): Real;
Здесь для ясности мы просто указали диапазон изменения функции Sin(x) и ее аргумента, ниже эта функция будет описана целиком. Параметры Xmax, Xmin, Ymax, Ymin - описаны со словом var потому что они являются входными-выходными, т.е. через них функция будет возвращать значения вычислений этих данных в основную программу. Поэтому надо объявить Xmax, Xmin, Ymax, Ymin как глобальные переменные в разделе implementation:
implementation
var Xmax, Xmin, Ymax, Ymin: Real;
Теперь поставим на форму кнопку и в ее обработчике события OnClick напишем следующий код:
procedure TForm1.Button1Click(Sender: TObject);
var
x, y: Real;
PX, PY: LongInt;
begin
for PX := 0 to Image1.Width do
begin
x := Xmin + PX * (Xmax - Xmin) / Image1.Width;
y := F(x, Xmax, Xmin, Ymax, Ymin);
PY := Trunc(Image1.Height - (y-Ymin) * Image1.Height / (Ymax-Ymin));
Image1.Canvas.Pixels[PX, PY] := clBlack;
end;
end;
В этом коде вводятся переменные x и y, являющиеся значениями аргумента и функции, а также переменные PX и PY, являющиеся координатами пикселей, соответствующих x и y. Сама процедура состоит из цикла по всем значениям горизонтальной координаты пикселей PX компонента Image1. Сначала выбранное значение PX пересчитывается в соответствующее значение x. Затем производится вызов функции F(x) и определяется ее значение Y. Это значение пересчитывается в вертикальную координату пикселя PY
Рисование с помощью пера Pen[править | править код]
У канвы имеется свойство Pen - перо. Это объект в свою очередь имеющий ряд свойств. Одно из них свойство Color - цвет, которым наносится рисунок. Второе свойство Width - ширина линии, задается в пикселах (по умолчанию 1).
Свойство Style определяет вид линии и может принимать следующие значения:
- psSolid - Сплошная линия
- psDash - Штриховая линия
- psDot - Пунктирная линия
- psDashDot - Штрих пунктирная линия
- psDashDotDot - Линия, чередующая штрих и два пунктира
- psClear - Отсутствие линии
- psInsideFrame - Сплошная линия, но при Width > 1 допускающая цвета, отличные от палитры Windows
Все стили со штрихами и пунктирами доступны только при толщине линий равной 1. Иначе эти линии рисуются как сплошные.
У канвы имеется свойство PenPos, типа TPoint. Это свойство определяет в координатах канвы текущую позицию пера. Перемещение пера без прорисовки осуществляется методом MoveTo(x, y). После вызова этого метода канвы точка с координатами (x, y) становится исходной, от которой методом LineTo(x, y) можно провести линию, в любую точку с координатами (x, y).
Давайте теперь попробуем нарисовать график синуса пером. Для этого добавим перед циклом оператор:
Image1.Canvas.MoveTo(0, Image1.Height div 2);
А перед заключительным end цикла добавьте следующий оператор:
Image1.Canvas.LineTo(PX, PY);
Таким образом у Вас должен получиться такой код:
procedure TForm1.Button1Click(Sender: TObject);
var
x, y: Real;
PX, PY: LongInt;
begin
Image1.Canvas.MoveTo(0, Image1.Height div 2);
for PX := 0 to Image1.Width do
begin
x := Xmin + PX * (Xmax-Xmin) / Image1.Width;
y := F(x, Xmax, Xmin, Ymax, Ymin);
PY := Trunc(Image1.Height - (y-Ymin) * Image1.Height / (Ymax-Ymin));
Image1.Canvas.Pixels[PX, PY] := clBlack;
Image1.Canvas.LineTo(PX, PY);
end;
end;
Как Вы уже успели заметить, если запустили программу, качество рисования графика пером, намного лучше, чем рисования по пикселям.
Как обещал сейчас напишу пример программы которая находит максимум и минимум функции. Я маленько изменил структуру процедур и функций, чтобы было яснее. Вот готовый код программы:
{...}
type
TForm1 = class(TForm)
Button1: TButton;
Image1: TImage;
procedure Button1Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
function F(x: Real): Real;
procedure ExtremMin(Xmax, Xmin: Real; var Ymin: Real);
procedure ExtremMax(Xmax, Xmin: Real; var Ymax: Real);
end;
var
Form1: TForm1;
implementation
const
e = 1e-4; // точность одна тысячная
var
Xmax, Xmin, Ymax, Ymin: Real;
{$R *.DFM}
function TForm1.F(x: Real): Real;
begin
F := Sin(x);
end;
// поиск минимума функции
procedure TForm1.ExtremMin(Xmax, Xmin: Real; var Ymin: Real);
var
x, h: Real;
j, n: Integer;
begin
n := 10;
repeat
x := Xmin;
n := n * 2;
h := (Xmax-Xmin) / n;
Ymin := F(Xmin);
for j := 1 to n do
begin
if f(x) < Ymin then
Ymin := f(x);
x := x + h;
end;
until Abs(f(Ymin) - f(Ymin + h)) < e;
end;
// поиск максимума функции
procedure TForm1.ExtremMax(Xmax, Xmin: Real; var Ymax: Real);
var
x, h: Real;
j, n: Integer;
begin
n := 10;
repeat
x := Xmin;
n := n * 2;
h := (Xmax-Xmin) / n;
Ymax := F(Xmin);
for j := 1 to n do
begin
if f(x) >= Ymax then
Ymax := f(x);
x := x + h;
end;
until Abs(f(Ymax) - f(Ymax + h)) < e;
end;
procedure TForm1.Button1Click(Sender: TObject);
var
x, y: Real;
PX, PY: LongInt;
begin
// здесь необходимо указать диапазон изменения x
Xmax := 8 * pi;
Xmin := 0;
// вычисляем экстремумы функции
ExtremMin(Xmax, Xmin, Ymin);
ExtremMax(Xmax, Xmin, Ymax);
// рисуем график функции
Image1.Canvas.MoveTo(0, Image1.Height div 2);
for PX := 0 to Image1.Width do
begin
x := Xmin + PX * (Xmax-Xmin) / Image1.Width;
y := F(x);
PY := Trunc(Image1.Height - (y-Ymin) * Image1.Height / (Ymax-Ymin));
Image1.Canvas.Pixels[PX, PY] := clBlack;
Image1.Canvas.LineTo(PX, PY);
end;
end;
end.
Ну вот и все, надеюсь эта статья оказалась Вам интересна!
Source: http://delphid.dax.ru
ID: 04216
Рисование синуса в PaintBox[править | править код]
procedure TForm1.Button3Click(Sender: TObject);
var
x, y: array[1..50] of Double;
i: Integer;
scalex, scaley, ymin, ymax, xmin, xmax: Double;
begin
for i := 1 to 50 do
begin
y[i] := Sin(i * 0.5);
x[i] := i;
end;
xmin := x[1];
xmax := x[1];
ymin := y[1];
ymax := y[1];
for i := 2 to 50 do
begin // или используйте ymin := MinValue(y); и т.д.
if y[i] < ymin then
ymin := y[i];
if y[i] > ymax then
ymax := y[i];
if x[i] < xmin then
xmin := x[i];
if x[i] > xmax then
xmax := x[i];
end;
scalex := PaintBox1.Width / (xmax - xmin);
scaley := PaintBox1.Height / (ymax - ymin);
with PaintBox1.Canvas do
begin
MoveTo(Trunc(scalex * (x[1] - xmin)), PaintBox1.height - Trunc(scaley * (y[1] - ymin)));
for i := 2 to 50 do
Lineto(Trunc(scalex * (x[i] - xmin)), PaintBox1.height - Trunc(scaley * (y[i] - ymin)));
end;
end;
Source: http://delphiworld.narod.ru/
ID: 04217
Рисование синусов в PaintBox[править | править код]
Забавная штука синусы:
for i := 1 to 500 do
PaintBox1.Canvas.Pixels[Round(Sin(i * 5) * 10 + 50), Round(Sin(i * 10) * 10 + 50)] := RGB(0, 0, 0);
Author: Baa
Source: Взято с Vingrad.ru http://forum.vingrad.ru
ID: 04218
Пример рисования функции на форме[править | править код]
unit grfunc_;
interface
uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs;
type
TForm1 = class(TForm)
procedure FormPaint(Sender: TObject);
procedure FormResize(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;
var
Form1: TForm1;
implementation
{$R *.DFM}
// Функция, график которой надо построить
function f(x: real): real;
begin
f := 2 * Sin(x) * exp(x / 5);
end;
// строит график функции
procedure GrOfFunc;
var
x1, x2: real; // границы изменения аргумента функции
y1, y2: real; // границы изменения значения функции
x: real; // аргумент функции
y: real; // значение функции в точке x
dx: real; // приращение аргумента
l, b: integer; // левый нижний угол области вывода графика
w, h: integer; // ширина и высота области вывода графика
mx, my: real; // масштаб по осям X и Y
x0, y0: integer; // точка - начало координат
begin
// область вывода графика
l := 10; // X - координата левого верхнего угла
b := Form1.ClientHeight - 20; // Y - координата левого верхнего угла
h := Form1.ClientHeight - 40; // высота
w := Form1.Width - 40; // ширина
x1 := 0; // нижняя граница диапазона аргумента
x2 := 25; // верхняя граница диапазона аргумента
dx := 0.01; // шаг аргумента
// найдем максимальное и минимальное значения
// функции на отрезке [x1,x2]
y1 := f(x1); // минимум
y2 := f(x1); // максимум
x := x1;
repeat
y := f(x);
if y < y1 then y1 := y;
if y > y2 then y2 := y;
x := x + dx;
until (x >= x2);
// вычислим масштаб
my := h / abs(y2 - y1); // масштаб по оси Y
mx := w / abs(x2 - x1); // масштаб по оси X
// оси
x0 := l;
y0 := b - Abs(Round(y1 * my));
with Form1.Canvas do
begin
// оси
MoveTo(l, b); LineTo(l, b - h);
MoveTo(x0, y0); LineTo(x0 + w, y0);
TextOut(l + 5, b - h, FloatToStrF(y2, ffGeneral, 6, 3));
TextOut(l + 5, b, FloatToStrF(y1, ffGeneral, 6, 3));
// построение графика
x := x1;
repeat
y := f(x);
Pixels[x0 + Round(x * mx), y0 - Round(y * my)] := clRed;
x := x + dx;
until (x >= x2);
TextOut(17, 100, 'Delphi World Example');
end;
end;
procedure TForm1.FormPaint(Sender: TObject);
begin
GrOfFunc;
end;
// изменился размер окна программы
procedure TForm1.FormResize(Sender: TObject);
begin
// очистить форму
Form1.Canvas.FillRect(Rect(0, 0, ClientWidth, ClientHeight));
// построить график
GrOfFunc;
end;
end.
Source: http://delphiworld.narod.ru/
ID: 04219
Пример выбора стиля для рисования функции[править | править код]
unit TestGrF;
interface
uses
Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
StdCtrls, ExtCtrls, DdhGraph;
type
TForm1 = class(TForm)
ColorDialog1: TColorDialog;
FontDialog1: TFontDialog;
Image1: TImage;
Panel1: TPanel;
Button1: TButton;
Button2: TButton;
CheckBox1: TCheckBox;
Button3: TButton;
DdhGraph1: TDdhGraph;
procedure Button1Click(Sender: TObject);
procedure Button2Click(Sender: TObject);
procedure CheckBox1Click(Sender: TObject);
procedure Button3Click(Sender: TObject);
private
{ Private declarations }
public
{ Public declarations }
end;
var
Form1: TForm1;
implementation
{$R *.DFM}
procedure TForm1.Button1Click(Sender: TObject);
begin
ColorDialog1.Color := DdhGraph1.Color;
if ColorDialog1.Execute then
DdhGraph1.Color := ColorDialog1.Color;
end;
procedure TForm1.Button2Click(Sender: TObject);
begin
FontDialog1.Font := DdhGraph1.Font;
if FontDialog1.Execute then
DdhGraph1.Font := FontDialog1.Font;
end;
procedure TForm1.CheckBox1Click(Sender: TObject);
begin
if CheckBox1.Checked then
DdhGraph1.BorderStyle := bsSingle
else
DdhGraph1.BorderStyle := bsNone;
end;
procedure TForm1.Button3Click(Sender: TObject);
begin
ColorDialog1.Color := DdhGraph1.LinesColor;
if ColorDialog1.Execute then
DdhGraph1.LinesColor := ColorDialog1.Color;
end;
end.
Source: http://delphiworld.narod.ru/
ID: 04220